Описание
Отменяет все предстоящие изменения объекта Recordset.

наборЗаписей.CancelUpdate тип

Параметры
наборЗаписей
Объектная переменная, представляющая объект Recordset, для которого отменяются отложенные обновления.
тип
Необязательный. Константа, указывающая тип обновления, как описано ниже (только в рабочей области ODBCDirect).

dbUpdateRegular		По умолчанию.  Отмена отложенных обновлений, не помещенных во временный буфер.
dbUpdateBatch		Отмена отложенных обновлений, находящихся во временном буфере.

Замечания
Метод CancelUpdate отменяет любые предстоящие операции обновления, являющиеся следствием вызова методов Edit или AddNew. Это означает, что если пользователь вызвал методы Edit или AddNew и еще не вызвал метод Update, то метод CancelUpdate приведет к отмене всех изменений, которые были следствием вызова методов Edit или AddNew.
Для того чтобы определить, имеются ли операции, которые можно отменить, следует проверить значение свойства EditMode объекта Recordset
Вызов метода CancelUpdate приводит к тем же результатам, как и переход на другую запись без вызова метода Update, с тем лишь исключением, что при этом не изменяется положение текущей записи и не изменяются значения таких свойств как BOF и EOF.

Пример
Следующая программа демонстрирует использование метода CancelUpdate с методом AddNew.

Sub CancelUpdateX()

	Dim dbsNorthwind As Database
	Dim rstEmployees As Recordset
	Dim intCommand As Integer

	Set dbsNorthwind = OpenDatabase("Борей.mdb")
	Set rstEmployees = dbsNorthwind.OpenRecordset(	"Сотрудники", bOpenDynaset)

	With rstEmployees
		.AddNew
		!Имя = "Иван"
		!Фамилия = "Петров"
		intCommand = MsgBox("Добавить запись для " & 	!Имя & " " & !Фамилия & "?", vbYesNo)
		If intCommand = vbYes Then
			.Update
			MsgBox "Запись добавлена."

			' Удаляет новую запись, 
			' добавленную для демонстрации.
			.Bookmark = .LastModified
			.Delete
		Else
			.CancelUpdate
			MsgBox "Запись не добавлена."
		End If
	End With
	dbsNorthwind.Close
End Sub